wow10。0DH巨集命令彙總 - 魔獸世界10。0DH巨集命令大全
魔獸世界10.0快上線了，在10.0版本職業天賦大改版，很多功能技能都需要玩家點天賦學習，導致一些巨集失效了，下面就給大家帶來魔獸世界10.0DH巨集命令大全，大家可以來參考一下。
魔獸世界10.0DH巨集命令大全
1.複雜的上馬巨集
/cancelaura 幽靈視覺
/use [nocombat]祕魔刃豹
/dismount [mounted]
/cast 滑翔
/cast [mod]疾影
/stopmacro [nocombat][channeling]
/target [@mouseover,harm]
/cast [@mouseover,harm] []邪能之刃
/stopmacro [@mouseover,noharm] [mod]
/targetlasttarget
/focus target
/targetlasttarget
功能解釋：
這個巨集我編在滑鼠側鍵，功能有點多
1.不在戰鬥則召喚坐騎，在戰鬥則使用[邪能之刃]
2.如果戰鬥中滑鼠指向了一個敵對目標，則切換該目標施放[邪能之刃]，並且把當前的目標設定為焦點
3.如果按下alt/shift/ctrl，則施放[疾影](不管在不在戰鬥狀態)
4.如果在天上就滑翔
5.取消[幽靈視覺]回到正常移速
運用場景：
你正開心的打著怪，突然來了優先順序更高的add，或者敵對玩家，你只需按一個鍵，就可以跳到這個目標身邊，並同時把當前正在打的目標設定成焦點。
然後就是上/下馬，空中飛一飛， 開個閃避 之類的
使用該巨集需要注意的問題：
1.快捷鍵不要衝突，假設這個巨集的快捷鍵是E,那[alt+E]，[shift+E]，[ctrl+E]別設定成快捷鍵，不然會使施放[疾影]的語句失效
2.注意與滑鼠指向目標的距離，如果超出距離，則無法使用[邪能之刃]
3.注意GCD，在技能轉GCD的時候忍著別按
下面是逐行註解，拋磚引玉，大家可以按自己習慣DIY
/cancelaura 幽靈視覺 ——如果有幽靈視覺則取消，吐槽一下，幽靈視覺的移動速度太慢了
/use [nocombat]祕魔刃豹 ——如果不在戰鬥，使用坐騎，我氪了基佬紫的這個豹， 感覺還挺好看的 ，這裡換坐騎可以先開啟坐騎的介面，在/use 語句後面按住shift點選你想用的坐騎
/dismount [mounted] ——如果在馬上，就下馬
/cast 滑翔 ——如果在天上，就[滑翔]，這裡的滑翔按第二下會取消，手速太快的可以寫成 /cast !滑翔，這樣滑翔就不會取消了
/cast [mod]疾影 ——如果同時按下alt/shift/ctrl，釋放[疾影]
/stopmacro [nocombat][channeling] ——如果不在戰鬥狀態，沒使用任何通道類技能(如眼稜、彈幕)，則巨集在這裡停止，這句的目的是優先把眼稜彈幕打完再施放其他技能
/target [@mouseover,harm] ——把滑鼠指向(並且可以攻擊的)目標設定為目標
/cast [@mouseover,harm] []邪能之刃 ——向滑鼠指向的(並且可以攻擊的)目標釋放[邪能之刃]，如果滑鼠沒有指向任何目標，則對當前目標使用[邪能之刃]
/stopmacro [@mouseover,noexists] [mod] ——如果滑鼠沒有指向任何目標，或者在alt/shift/ctrl按下時，則巨集在這裡停止，這句的目的是為了在對當前目標進行[邪能之刃]時，不改變當前焦點(如果有的話)
/targetlasttarget ——選擇上一個目標(如果巨集執行到這兒了，這裡的lasttarget指的是add前你正在打的那個目標，你現在的目標已經是add了，我們選擇add前這個目標)
/focus target ——並把這個目標設定為焦點
/targetlasttarget ——選擇上一個目標(上一個目標指的是add，巨集到這裡完成了把add前的目標設定為焦點，並把add設定成當前目標)
2.禁錮巨集
#showtooltips 禁錮
/cast [@mouseover,exists] [mod,@focus,exists]禁錮
/focus [@mouseover,exists]
/stopmacro [@mouseover,noexists] [mod]
/cast 禁錮
/focus target
/cancelaura 獻祭光環
/stopattack
功能解釋：
1.如果滑鼠指向的目標是敵對的就[禁錮]它，並把它設定成焦點
2.如果滑鼠沒指向任何目標就[禁錮]當前的目標
2.如果按了alt/shift/ctrl，就禁錮焦點
3.如果是對當前目標使用禁錮，就取消獻祭光環，停止自動攻擊，免得沒有天賦支援的時候燒醒了
運用場景：
滿足任何需要[禁錮]技能的情況
使用該巨集需要注意的問題：
1.快捷鍵不要衝突，假設這個巨集的快捷鍵是E,那[alt+E]，[shift+E]，[ctrl+E]不要設定成快捷鍵，不然會使對焦點施放[禁錮]的語句失效
2.注意與滑鼠指向目標的距離，如果超出距離，則無法使用[禁錮]
逐行註解
/cast [@mouseover,exists] [mod,@foucs,exists]禁錮 ——對滑鼠指向的目標施放[禁錮]，如果按了alt/shift/ctrl，就禁錮焦點
/focus [@mouseover,exists] ——把滑鼠指向的目標設定成焦點
/stopmacro [@mouseover,exists,harm][mod] ——如果滑鼠指向有可以攻擊的目標 或者 按了alt/shift/ctrl 巨集在這裡結束，這樣就不會在[禁錮]其他(遠距離)目標時停止攻擊當前的目標或取消獻祭。
/cast 禁錮 ——對當前目標施放禁錮
/focus target ——把當前目標設定成焦點
/cancelaura 獻祭光環 ——取消獻祭光環
/stopattack ——停止攻擊
3.鬼畜贊怒巨集
#showtooltip
/cancelaura 虛空行走
/f
/stopmacro [help][channeling]
/cast [harm]惡魔之咬
/cast [harm]裂魂
/cast !滑翔
/cast [combat,noexists][mod]幽靈視覺
/stopmacro [harm]
/targetlasttarget
功能解釋：
1.打惡魔之咬，如果目標是友方就跟隨
2.取消虛空行走，繼續開擼
3.戰鬥時，如果突然沒了目標就開[幽靈視覺]選擇丟失的目標 ——這行對盜賊、法師很不友好
4.被boss擊飛時，開滑翔，不會飛太遠
逐行註解
#showtooltip
/cancelaura 虛空行走 ——取消虛空行走
/f ——跟隨目標
/stopmacro [help][channeling] ——如果當前目標為友方 或者 在施放通道魔法則巨集在這停止
/cast [harm]惡魔之咬
/cast [harm]裂魂
/cast !滑翔 ——不在地上就滑翔
/cast [combat,noexists][mod]幽靈視覺 ——戰鬥中沒有目標或者按下alt/shift/ctrl，就施放[幽靈視覺]
/stopmacro [harm] ——如果當前有可攻擊的目標 巨集在這停止
/targetlasttarget ——(如果戰鬥中沒有目標 就)選擇上一個目標
4.焦點與目標互換巨集
/cleartarget [@target,dead]
/clearfocus [@focus,dead]
/target [@focus,harm]
/cast 邪能之刃
/targetlasttarget
/focus target
/targetlasttarget
功能解釋：
1.把當前目標設定為焦點
2.把當前焦點設定為目標
運用場景：
轉火!轉火!轉火!
這裡順帶說一下，因為DH的位移技能只有邪能之刃是目標指向的，才15碼而且有GCD，所以效果並沒有[暗影步][衝鋒]好，如果你有戰士或者DZ，本巨集實用性會大大提高，值得擁有!
逐行註解
/cleartarget [@target,dead] ——如果目標死亡就清除目標(相當於點地板)
/clearfocus [@focus,dead] ——如果焦點死亡就清除焦點
/target [@focus,harm] ——把焦點設定為目標(如果有焦點而且焦點是敵對目標)
/cast 邪能之刃
/targetlasttarget ——選擇上一個目標(這裡指的是焦點變為目標前的那個目標)
/focus target ——把這個目標設定為焦點
/targetlasttarget ——選擇上一個目標(也就是按下巨集鍵前的焦點目標)
另外附上一個暗影步版加了滑鼠指向的一鍵轉火巨集
比單純的滑鼠指向巨集方便，因為目標跟著一起切換了，真正做到了一鍵
而且轉火前的目標或成為新的焦點
/clearfocus [@focus,dead]
/cast [nostealth]!潛行
/target [@mouseover,harm]
/target [mod,@focus,harm]
/cast 暗影步
/stopmacro [@mouseover,noexists] [nomod]
/targetlasttarget
/focus target
/targetlasttarget
5.投擲巨集
#showtooltips 投擲利刃
/clearfocus [@focus,dead]
/cast [@mouseover,harm] [mod,@focus,exists][]投擲利刃
/stopmacro [@focus,exists,harm]
/focus [@mouseover,harm]
功能解釋：
與禁錮巨集一樣的原理
1.向滑鼠指的目標[投擲利刃]，如果此時你沒有焦點，就把它設定為焦點
2.按下alt/shift/ctrl時就對焦點目標投擲利刃
3.滑鼠沒目標就對當前目標投擲利刃
使用場景：
在不影響當前作戰目標的情況下，向add[投擲利刃]並設定新焦點，為轉火做前戲或者就是單純想關愛一下焦點
逐行註解
#showtooltips 投擲利刃
/clearfocus [@focus,dead] ——如果焦點目標已經死亡就取消焦點
/cast [@mouseover,harm] [mod,@focus,exists][]投擲利刃 ——向滑鼠指的目標[投擲利刃]，如果按下alt/shift/ctrl，就對焦點目標[投擲利刃]，如果滑鼠沒目標，也沒按下alt/shift/ctrl，就對當前目標[投擲利刃]
/stopmacro [@focus,exists,harm] ——如果已經有焦點了並且焦點是可以攻擊的物件 巨集在這裡停止，這是為了保證已有焦點不會被更換
/focus [@mouseover,harm] ——把滑鼠指向的目標設定為焦點
6.其他
對DH來講比較實用的巨集語句
/stopmacro [channeling] ——如果當前在施放通道魔法則巨集在這裡停止，這一條可以加在所有的鬼畜巨集的第一句，來保護[眼稜]和[彈幕]的完整施放
/cancelaura 虛空行走 ——取消虛空行走(被奶回來了，別傻站著)
/cancelaura 幽靈視覺 ——取消幽靈視覺(幽靈視覺的減速很討厭)
/cancelaura 獻祭光環 ——取消獻祭光環(不打破別人控制技能 不額外add小怪)
/cancelaura 惡魔踐踏 ——取消惡魔踐踏(撞倒就好了，不用一直跑)
/cast [@cursor] xxx技能 如[惡魔變形][暴風雪][擾亂] ——在滑鼠指標的位置一鍵施放無目標類技能，個人很不建議把[惡魔變形]做成一鍵施放，非常珍貴的位移加控制，需要保證精度，尤其在水裡的時候，Z軸的判定非常奇葩
/cast [@player] xxx技能 如[烈焰咒符] ——以自己為中心一鍵施放無目標類技能
/cast !惡魔變形 ——在技能前加一個"!"即使你鬼畜按很多下，也不會讓施法圈消失
DH沒有GCD的技能(可以加在任何巨集裡又不影響巨集使用)
通用：[滑翔][折磨][瓦解][角鬥士勳章][潛行(暗夜精靈)]
浩劫：[疾影]
復仇：[惡魔尖刺][地獄火撞擊](地獄火撞擊只跟地獄火撞擊有GCD)
人人都有兩個目標，當前目標和焦點目標，你可以藉助WA外掛隨時掌控兩個目標的一切行為和動向，並在PVP的時候做出最佳決策。
強烈建議用WA加入焦點距離的判定提示，≤15碼、≤20碼、≤30碼、無限遠 以便隨時的控制或轉火。
